/*
 * ListeningHistory - Represents the listening history of a user. Contains weeks which reference artists.
 */
class ListeningHistory{

  int totalPlays;   // total plays within this history
  String username;  // the Last.FM username
  Artists artists;  // reference to the list of artists
  Weeks weeks;      // reference to the list of weeks

  ListeningHistory(String username){
    this.username = username;
    totalPlays = 0;

    artists = new Artists(this);
    weeks = new Weeks(this);
  }

  int getTotalPlays(){
    return totalPlays;
  }

  Artists getArtists(){
    return artists;
  }

  Weeks getWeeks(){
    return weeks;
  }
  
  ListeningHistory filterByPopularity(float popularity){
    return filterByPopularity(1, popularity);
  }

  ListeningHistory filterByPopularity(float max, float min){

    // create a new history file
    ListeningHistory filteredHistory = new ListeningHistory(this.username);
    
    // loop through the weeks
    for(int w=0; w<weeks.getCount(); w++){
      
      // get this week
      Week week = weeks.getWeek(w);
      
      // create the new week
      Week filteredWeek = filteredHistory.weeks.addWeek(week.getDate());
      
      // loop through artists
      for(int a=0; a<week.getCount(); a++){
        
        // get this artist
        Artist artist = week.getArtist(a);
        
        // if it meets our popularity threshold...
        if(artist.getPopularity()<= max && artist.getPopularity() >= min){
          
          // create a new artist
          Artist newArtist = filteredHistory.artists.addArtist(artist.getName());
          
          // add the artist to the week lineup
          filteredWeek.addArtist(newArtist);

          // add the plays to the artist for this particular week
          newArtist.addPlays(filteredWeek, artist.getPlays(week));
          
        }
      }
    }
    
    // return the new history data
    return filteredHistory;
    
  }

  void loadData(){

    // get the data file
    BufferedReader data = createReader("data/histories/"+username+".dat");

    try{
      // first line: load in how many weeks there are
      String[] header = split(data.readLine(),",");
      int weekCount = int(header[1]);

      // skip a line
      data.readLine();

      // read in the weeks
      for(int w=0; w<weekCount; w++){

        // first line get timestamp and count
        String[] weekHeader = split(data.readLine(),",");
        long timestamp = (long) float(weekHeader[0]);
        int artistCount = int(weekHeader[1]);

        // create the new week
        Week week = weeks.addWeek(timestamp);

        // loop through to get artists
        for(int a=0; a<artistCount; a++){

          // read line to get name and count
          String[] artistLine = split(data.readLine(),",");
          String name = artistLine[0];
          int playCount = int(artistLine[1]);

          // create the new artist
          Artist artist = artists.addArtist(name);

          // add the artist to the week lineup
          week.addArtist(artist);

          // add the plays to the artist for this particular week
          artist.addPlays(week, playCount);
        }

        // skip a line
        data.readLine();

      }
    }
    catch(IOException e){
      e.printStackTrace();
    }
  }

}